emacs 的 customization

为了方便起见，接下来所有的代码都是在叫做 yyvar 的组中完成的，它的定义是：

(defgroup yyvar nil
  "var test"
  :group 'editing)

这里我没有把所有的类型都列出来，这样做没什么意义，而且等到文档发生变化了我也不一定会更新。这里我会介绍一些看上去比较简单和常用的类型。

:type 描述了两件事：（1）什么值是合理的（2）如何在自定义界面显示值来进行编辑，这一点通常和组合类型有关。

:type 接受的参数只会被求值一次，即在 defcustom 被求值时，因此一般使用 quoted 的常值作为它的参数。一般来说，它的参数是一个表，表首元素是一个符号，随后是一些参数。

首先我们介绍一些简单的类型，以它们作为类型时只需要表首元素来作为 :type 的参数即可，比如这样：

(defcustom one "123"
  "one custom"
  :type '(string))
;; the same, without paren
(defcustom one "123"
  "one custom"
  :type 'string)

除了上面的 string 外，简单类型还有： sexp 、 integer 、 number 、 float 、 regexp 、 character 、 file 、 hook 、 symbol 、 function 、 variable 等。

接下来是一些复合类型，它们的语法是 (constructor arguments ...) ， constructor 用于指示组合的方式， argument 指明具体的类型。比较常见的复合类型有：

• 序对类型： (cons car-type cdr-type) ，它表明选项的值必须是序对， car 部分必须是 car-type 类型， cdr 必须是 cdr-type 类型。在自定义界面上 car 和 cdr 是分开显示的：就像这样：

(defcustom yycon '(1 . 2)
  "yy's cons"
  :type '(cons integer integer))

(setq yycon '(3 . 4))

在自定义界面上它的显示方式是这样：

• 表类型： (list element-types ...) ，表长和表中各个值的类型必须与类型匹配

(defcustom yylst '(1 wo "123")
  "yy's list"
  :type '(list integer symbol string))

表示表类型的除了 list 还有 group ，不过 group 不会显示使用 tag 注释的选项名，两者的差别可以通过以下代码体现：

(defcustom yyl1 '(3 4)
  "yy l1"
  :tag "hao"
  :type '(group integer integer))

(defcustom yyl2 '(1 2)
  "yy l2"
  :tag "le"
  :type '(list integer integer))

• 向量类型： (vector element-types ...) ，除了向量和表不是同种类型，其他各项指标都一样
• 关联表： (alist :key-type key-type :value-type value-type) ，用户可以添加/删除键值对，并对键和值进行修改。如果忽略了类型，键和值的类型就默认为 sexp

这个时候， :options 的价值就体现出来了，在 :options 中指定的键会在自定义界面中显示，旁边有一个按钮来让它加入关联表或从关联表中删除。用户不能对其进行修改。

:options 参数格式是 '(key1 key2 key3 ...) ，这是最简单的一种，其他高级玩法见文档。

(defcustom yyal '((1 . 2) (2 . 3))
"yy's alist"
:type '(alist :key-type integer :value-type integer)
:options '(4 5 6))

• 属性表： (plist :key-type key-type :value-type value-type) ，和关联表基本一致，但是键值以属性表的形式存储
• 选择： (choice alternative-types ...) ，它有多种类型可选，值必须是这些类型中的一种，比如 (choice string integer)

如果某个值满足 choice 中的多种类型的话，那么最早出现在 choice 中的类型会被选择，这意味着在列写 choice 时应注意将最特殊的类型放在最前面，最一般的类型放在最后面。

还有一种类型和 choice 是一样的，它叫做 radio ，但是它使用圆形按钮而不是菜单来显示选择。

(defcustom yyco 123
"yy's choice"
:type '(choice
    (string :tag "str")
    (integer :tag "int")
    (symbol :tag "sym")))

choice:

(defcustom yyrad 123
"yy's radio"
:type '(radio string integer symbol))

radio:

• 常值： (const value) ，这里的 value 必须是一个值， const 主要配合 choice 使用，用来作为某个选项。

与之相似但很不一样的有 other ，相似是指它们都接受一个值，不同指 ohter 可以接受任意的值，比如一个变量。

• 函数项： (function-item function) ，和 const 很像，但它专门用于函数，它可以在自定义界面中显示函数的各种信息。

和函数项相似的还有变量项 variable-item ，它可以显示变量的信息。

(defun add (x y)
  "add two number"
  (+ x y))
(defcustom yyfun-val 1
  "yy's fun and val item"
  :type '(radio (function-item add)
                (variable-item lexical-binding)
                integer))

• 集合： (set types ...) 和重复 ： (repeat elemet-type) ，前者表明值是一张表，表中元素的类型可以是集合中指定的任意一种，后者则要求表中只能由指定的那一种类型。
• 限制的sexp： (restricted-sexp :match-alternatives criteria) ，这是最通用的一种组合类型，通过指定满足条件即可，例子可见文档

类型方面的介绍就到这里，你看累了，我也写累了。文档上还有一些辅助关键字以及定义新类型的方法，通俗易懂，意犹未尽的同学可以去看看。

通过上面的例子也看到了，想要改变一个选项的值，首先在灰色输入框中输入值，然后单击（或Enter键） State 按钮来进行修改。如果我们不设置 :set 的话，Emacs 会使用默认的 set-default 来对选项进行设置，设置 :set 可以改变这一默认行为：

(fset 'yyse (lambda (sb va) (set sb (+ va 1))))

(defcustom yyset1 1
"yy's set1"
:type 'integer
:set 'yyse)

这段代码就比较有意思了，变量的初始化值为 1，但是在自定义界面显示的值却是 2，将变量设置为 3，最后得到的却是 4。这就是 :set 的作用。当使用自定义界面来设置选项的值时，set 函数会接受这个输入的值，对其进行处理后再更新选项。

至于 :get 关键字，它的作用是返回一个值以便显示：（这里使用了 dash 库的 -map 函数，和 mapcar 一个意思）

(defcustom b '(1 2 3)
"yy's b"
:type '(repeat integer)
:get (lambda (s) (-map  (lambda (x) (+ x 1)) (symbol-value s))))

这是对定义求值后得到的自定义界面：

这个关键字参数指定在初始化时一些行为，这里我主要对 Emacs 提供的五个函数进行一些分析。

custom-initialize-set 在初始化时使用 :set 提供的函数来进行初始化。如果变量已经非空了就不进行初始化。

custom-initialize-default 则使用 set-default 来作为初始化函数。变量非空则不初始化。

custom-initialize-reset 总是使用 :set 函数来初始化选项。如果变量在初始化之前已被绑定，则使用由 :get 函数得到的值来调用 :set 函数，这是默认的 :initialize 函数。

custom-initialize-changed ，如果变量非空，则使用 :set 函数对选项初始化，否则使用 set-default 。

custom-initialize-delay ，它的行为和第一个函数很像，但是它延迟到下一个 Emacs 启动时才进行实际的初始化。它一般用在预载入（Preload）文件中。

对前四个函数可以写出一些代码来验证其特性：

set:

;; custom-initialize-set
;; 1. with void variable
(defcustom s1 1 ""
  :type 'number
  :initialize 'custom-initialize-set
  :set (lambda (s x) (set s (+ x 1))))
s1 => 2

;; 2. with non-void variable
(setq s1 1)
(defcustom s1 1 ""
  :type 'number
  :initialize 'custom-initialize-set
  :set (lambda (s x) (set s (+ x 1))))
s1 => 1

default:

;; 1. with void variable
(defcustom s2 1 ""
:type 'number
:initialize 'custom-initialize-default)
s2 => 1
;; 2. with non-void variable
(setq s2 2)
(defcustom s2 1 ""
:type 'number
:initialize 'custom-initialize-default)
s2 => 2

reset:

;; 1. with void variable
(defcustom s3 1 ""
:type 'number
:initialize 'custom-initialize-reset
:set (lambda (s x) (set s (+ x 1))))
s3 => 2
;; 2. with non-void variable
(setq s3 2)
(defcustom s3 1 ""
:type 'number
:initialize 'custom-initialize-reset
:set (lambda (s x) (set s (+ x 1))))
s3 => 3

changed:

;; 1. with void variable
(defcustom s4 1 ""
  :type 'number
  :initialize 'custom-initialize-changed
  :set (lambda (s x) (set s (+ x 1))))
s4 => 1
;; 2. with non-void variable
(setq s4 2)
(defcustom s4 1 ""
  :type 'number
  :initialize 'custom-initialize-changed
  :set (lambda (s x) (set s (+ x 1))))
s4 => 3

:local ， :risky ， :safe 这几个关键字我直接过了，因为它们都是用来设置属性值的，但是我现在还不太清楚设置了到底有什么用。

:set-after 可以保证选项在其他变量被设定完毕后再进行设定，它应该被用在某些要求顺序设定的场合：

要验证这一点需要两个文件（当然一个也行，在文件内对 custom-set-variable 求值即可），一个存放 defcustom 叫做 2.el， 另一个存放 custom-set 叫做 my.el，两文件在同一目录下：

;; my.el
(custom-set-variables
 '(w3 1)
 '(w2 1)
 '(w1 1))

首先我们看看不加 :set-after 会有什么后果：

;; 2.el
;; wrong
(setq cnt 0)
(defgroup wcd nil ""
  :group 'wp)

(defcustom w1 2 ""
  :type 'number
  :set (lambda (s v) (progn (cl-incf cnt) (set s cnt)))
  :initialize 'custom-initialize-default)

(defcustom w2 3 ""
  :type 'number
  :set (lambda (s v) (progn (cl-incf cnt) (set s cnt)))
  :initialize 'custom-initialize-default
  ;;:set-after '(w1)
  )

(defcustom w3 4 ""
  :type 'number
  :set (lambda (s v) (progn (cl-incf cnt) (set s cnt)))
  :initialize 'custom-initialize-default
  ;;:set-after '(w2)
  )

(load-file  "./my.el")load-file  "./my.el")

可以看到， w3 为 1， w2 为 2， w1 为 3。这是它们在 my.el 文件中出现的顺序，如果我们要求按照 w1, w2, w3 的顺序来初始化呢？这个时候就需要用到 :set-after 了。让我们删掉 :set-after 上面的注释再试一次：

这样就完成了顺序初始化。

另：如果将上面的 mysel.el 中的内容改成：

(custom-set-variables
 '(w3 1))
(custom-set-variables
 '(w2 1))
(custom-set-variables
 '(w1 1))

即使在指定了顺序的情况下，得到的结果仍然是 w3 为 1， w2 为 2， w1 为 3。这一点我还不明所以。或许和 custom-set-variables 的内部机制有关。

在文档中提到的函数有：

• custom-add-frequent-value
• custom-reevaluate-setting
• custom-variable-p
• custom-set-variables
• custom-set-faces

这些函数中，用的最多的应该是第四个，即 custom-set-variables ，这里我只对它进行介绍，因为其他的函数我似乎找不到具体的应用方法。

custom-set-variables 用于安装自定义变量，它接受可变个数参数，每个参数的格式是：

(var expression [now [request [comment]]]) ，上面的例子中我给出了简单的使用方法。

其中，var 是变量名，expression 是作为变量值的待求值表达式，now, request 和 comment 仅在内部使用，它们应该被忽略。

使用 custom-set-variables 相当于调用 :set 函数，如果直接使用 setq 的话则不会调用 :set 函数。

如果 defcustom 在 custom-set-variables 调用之前就被求值过，那么变量的值会被设置为 custom-set-variables 求值得到的结果。如果 defcustom 在 custom-set-variables 求值之后的话，expression 会被存放在变量的 saved-value 属性中，当对应的 defcustom 被求值时 expression 才会被求值。